Shareware Grab Bag/Shareware Grab Bag.iso/003/db2ios.arc/SEARCH.SIG

Text File | 1983-01-04 | 3.9 KB | 128 lines

* search.sig 08/18/83
* index search program with ability to edit, delete, print, print voucher
STORE t TO first
STORE t TO more
DO WHILE more
    IF first
        STORE CHR(PEEK (063)) TO dr
        USE &dr.:sig/m INDEX &dr.:orders
        ERASE
        STORE 'Search for record by <L>ast name or <A>ny part of data base' TO prompt1
        STORE '<B>ackward or <F>orward, <D>elete/Recall, <E>dit' TO prompt2
        STORE '<P>rint, <V>oucher or <Q>uit searching' TO prompt3
        STORE  'Record Search Module' TO mode
        @  1,25 SAY mode
        @  2, 0 SAY "+--------------------------------------"
        @  2,39 SAY "----------------------------------------+"
        @  3, 5 SAY "ORDER NUMBER:"
        @  3,43 SAY "Complete:"
        @  4, 8 SAY "Last name:"
        @  4,46 SAY "First:"
        @  5,10 SAY "Address:"
        @  6, 9 SAY "(line 2):"
        @  7, 9 SAY "(line 3):"
        @  8,13 SAY "City:"
        @  8,46 SAY "State:"
        @  8,65 SAY "ZIP:"
        @ 10, 2 SAY "Volumes:"
        @ 12, 3 SAY "Amount:"
        @ 12,46 SAY "Enter:"
        @ 12,64 SAY "Ship:"
        @ 13, 2 SAY "Remarks:"
        @ 14, 2 SAY "Remarks:"
        @ 16, 0 SAY "Backorder:"
        @ 17,44 SAY "Catalog:"
        @ 18, 2 SAY "Shipped:"
        @ 18,26 SAY "Shipped:"
        @ 18,62 SAY "Update:"
        @ 19, 0 SAY "+--------------------------------------"
        @ 19,39 SAY "----------------------------------------+"
        @ 20,12 SAY prompt1
        @ 21,12 SAY prompt2
        @ 22,12 SAY prompt3
    ENDIF first
    STORE f TO first
    STORE 'L' TO command
    STORE '                     ' to name
    IF *
        STORE 'Deleted' TO deleted
    ELSE
        STORE '       ' TO deleted
    ENDIF *
    @  1, 0 SAY deleted
    @  3,19 SAY order
    @  3,53 SAY comp
    @  4,19 SAY lname
    @  4,53 SAY fname
    @  5,19 SAY addr1
    @  6,19 SAY addr2
    @  7,19 SAY addr3
    @  8,19 SAY city
    @  8,53 SAY state
    @  8,70 SAY zip
    @ 10,11 SAY vol1
    @ 12,11 SAY amt using '$###.##'
    @ 12,53 SAY entered
    @ 12,70 SAY shipped
    @ 13,11 SAY rem1
    @ 14,11 SAY rem2
    @ 16,11 SAY bo
    @ 17,53 SAY catalog
    @ 18,11 SAY bo:ship
    @ 18,35 SAY bo2:ship
    @ 18,70 SAY dayu
    @ 22,56 SAY 'WHAT NEXT?'
    @ 22,70 GET command PICTURE '!'
    READ
    CLEAR GETS
    DO CASE
        CASE command = 'A'
            DO search1.sig
        CASE (command = 'B' .OR. command = ',')
            SKIP -1
        CASE command = 'D'
            IF *
                RECALL
            ELSE
                DELETE
            ENDIF
        CASE (command = 'F' .OR. command = '.')
            SKIP
        CASE command = 'E'
            DO edit.sig
        CASE command = 'P'
            DO print.sig
        CASE command = 'V'
            DO voucher.sig
        CASE command = 'L'
            STORE # TO rec:number
            @ 20,00
            @ 21,00
            @ 22,00
            @ 20,12 SAY 'Please enter Last Name' GET name
            READ
            STORE TRIM(name) TO name
            STORE !(name) TO name
            FIND &name
            @ 20,12 SAY '                                                           '
            IF # = 0
                @ 20,00
                @ 20,12 SAY name+' is not in the file'
                @ 21,12 SAY 'Press RETURN to Continue'
                SET CONSOLE OFF
                WAIT
                SET CONSOLE ON
                GOTO rec:number
                @ 20,00
                @ 21,12 SAY '                                                           '
            ENDIF #=0
            @ 20,12 SAY prompt1
            @ 21,12 SAY prompt2
            @ 22,12 SAY prompt3
        CASE command = 'Q'
            STORE  f  TO more
    ENDCASE
ENDDO while more
RELEASE ALL
STORE t TO first